atlcloudjira_project (Resource)

Example Usage

/*
List of available project type key <-> Project Template Key value pairs
Project Type Key	Project Template Key
business -      com.atlassian.jira-core-project-templates:jira-core-simplified-content-management,
                com.atlassian.jira-core-project-templates:jira-core-simplified-document-approval,
                com.atlassian.jira-core-project-templates:jira-core-simplified-lead-tracking,
                com.atlassian.jira-core-project-templates:jira-core-simplified-process-control,
                com.atlassian.jira-core-project-templates:jira-core-simplified-procurement,
                com.atlassian.jira-core-project-templates:jira-core-simplified-project-management,
                com.atlassian.jira-core-project-templates:jira-core-simplified-recruitment,
                com.atlassian.jira-core-project-templates:jira-core-simplified-task-tracking

service_desk -  com.atlassian.servicedesk:simplified-it-service-management,
                com.atlassian.servicedesk:simplified-general-service-desk-it,
                com.atlassian.servicedesk:simplified-general-service-desk-business,
                com.atlassian.servicedesk:simplified-external-service-desk,
                com.atlassian.servicedesk:simplified-hr-service-desk,
                com.atlassian.servicedesk:simplified-facilities-service-desk,
                com.atlassian.servicedesk:simplified-legal-service-desk,
                com.atlassian.servicedesk:simplified-analytics-service-desk,
                com.atlassian.servicedesk:simplified-marketing-service-desk,
                com.atlassian.servicedesk:simplified-design-service-desk,
                com.atlassian.servicedesk:simplified-sales-service-desk,
                com.atlassian.servicedesk:simplified-blank-project-business,
                com.atlassian.servicedesk:simplified-blank-project-it,
                com.atlassian.servicedesk:simplified-finance-service-desk,
                com.atlassian.servicedesk:next-gen-it-service-desk,
                com.atlassian.servicedesk:next-gen-hr-service-desk,
                com.atlassian.servicedesk:next-gen-legal-service-desk,
                com.atlassian.servicedesk:next-gen-marketing-service-desk,
                com.atlassian.servicedesk:next-gen-facilities-service-desk,
                com.atlassian.servicedesk:next-gen-general-it-service-desk,
                com.atlassian.servicedesk:next-gen-general-business-service-desk,
                com.atlassian.servicedesk:next-gen-analytics-service-desk,
                com.atlassian.servicedesk:next-gen-finance-service-desk,
                com.atlassian.servicedesk:next-gen-design-service-desk,
                com.atlassian.servicedesk:next-gen-sales-service-desk

software -      com.pyxis.greenhopper.jira:gh-simplified-agility-kanban,
                com.pyxis.greenhopper.jira:gh-simplified-agility-scrum,
                com.pyxis.greenhopper.jira:gh-simplified-basic,
                com.pyxis.greenhopper.jira:gh-simplified-kanban-classic,
                com.pyxis.greenhopper.jira:gh-simplified-scrum-classic

The project types are available according to the installed Jira features as follows:
 - Jira Core, the default, enables     *business*      projects.
 - Jira Service Management enables     *service_desk*  projects.
 - Jira Software enables               *software*      projects.

To determine which features are installed, go to Jira settings > Apps > Manage apps and review the System Apps list.
To add Jira Software or Jira Service Management into a JIRA instance, use Jira settings > Apps > Finding new apps.

You cannot change PROJECT_TYPE nor PROJECT_TEMPLATE_KEY after the project is created.
*/

import {
  to = atlcloudjira_project.SampleCompanyManagedProjectResource
  id = 10067
}
# __generated__ by Terraform
# Please review these resources and move them into your main configuration files.

# __generated__ by Terraform from "10067"
resource "atlcloudjira_project" "SampleCompanyManagedProjectResource" {
  // Minimum required attributes
  key              = "SAMPLET1"
  name             = "Sample project 1"
  assignee_type    = "PROJECT_LEAD" // Valid values: PROJECT_LEAD, UNASSIGNED
  project_type_key = "software"     // Valid values: software, service_desk, business

  // Optional attributes
  avatar_id                  = 10417
  category_id                = 10000
  description                = "Sample description"
  field_configuration_scheme = null // When set to null, System Default Field Configuration Scheme is assigned.
  lead_account_id            = "80dacb68-6f79-46c6-b22e-296669e36568"
  url                        = "https://sample.atlassian.net/jira/projects"
  excluded_roles             = null    // Helper attribute. Can be null. Allow to exclude roles and manage only remaining project roles.
  included_roles             = [10002] // Helper attribute. Can be null. Allow to include and manage only selected project roles.
  project_roles = {
    10002 = {
      groups = null
      users  = ["80dacb68-6f79-46c6-b22e-296669e36568", "5fde5ea73b5e47013845900a"]
    }
  }

  // Share configuration schemes cannot be set during cration with project_template_key. Create and reimport resource if needed.
  issue_security_scheme    = 10000 // Cannot be set during creation when project_template_key is set
  issue_type_scheme        = 10233 // Cannot be set during creation when project_template_key is set
  issue_type_screen_scheme = 10000 // Cannot be set during creation when project_template_key is set
  notification_scheme      = 10001 // Cannot be set during creation when project_template_key is set
  permission_scheme        = 10001 // Cannot be set during creation when project_template_key is set
  workflow_scheme          = 10022 // Cannot be set during creation when project_template_key is set

  project_template_key = null // Cannot import this attribute. Can be set only during creation and can't be changed. See list above.
}

Schema

Required

• assignee_type (String) The default assignee type when creating issues for this project. Valid values: PROJECT_LEAD, UNASSIGNED

• key (String) Project keys must be unique and start with an uppercase letter followed by one or more uppercase alphanumeric characters. The maximum length is 10 characters.

• lead_account_id (String) Project lead account ID.

• name (String) The name of the project.

• project_type_key (String) The project type, which defines the application-specific feature set. If you don't specify the project template you have to specify the project type.

Optional

• avatar_id (Number) An integer value for the project's avatar.

• category_id (Number) The ID of the project's category.

• description (String) A brief description of the project.

• excluded_roles (Set of Number) Set of project roles IDs excluded from Terraform management.

• field_configuration_scheme (Number) The ID of the field configuration scheme for the project. When null, field configuration scheme is set to default.

• included_roles (Set of Number) Set of project roles IDs to be managed by Terraform.

• issue_security_scheme (Number) The ID of the issue security scheme for the project, which enables you to control who can and cannot view issues.

• issue_type_scheme (Number) The ID of the issue type scheme for the project.

• issue_type_screen_scheme (Number) The ID of the issue type screen scheme for the project.

• notification_scheme (Number) Project notification scheme ID.

• permission_scheme (Number) The ID of the permission scheme for the project.

• project_roles (Attributes Map) Map of selected project role IDs and actors assigned to given project role. (see below for nested schema)

• project_template_key (String) A predefined configuration for a project. The type of the projectTemplateKey must match with the type of the projectTypeKey. If project is team managed, do not combine it with configuration schemes.

• url (String) A link to information about this project, such as project documentation.

• workflow_scheme (Number) The ID of the workflow scheme for the project.

Read-Only

• id (Number) The project ID.

• last_updated (String) Timestamp of the last Terraform update of the project.

Nested Schema for project_roles

Optional:

• groups (Set of String) Set of Group Ids assigned to given Project Role.

• users (Set of String) Set of User Account Ids assigned to given Project Role.